[Copyright 1982,1983,2000,2002 Frank Durda IV, All Rights Reserved. Mirroring of any material on this site in any form is expressly prohibited. The official web site for this material is: http://nemesis.lonestar.org Contact this address for use clearances: clearance at nemesis.lonestar.org Comments and queries to this address: web_software_2011 at nemesis.lonestar.org]
Did some stupid search engine drop you here?
Visit the PERIOD Index page first!
The Model 100 version of the PERIOD.BA code is presented here. The minor changes needed to make the program work on the PC-DOS/MS-DOS 3.3 BASIC interpreter are shown elsewhere.
To begin, here is an explanation on why the actual program has no REM statements.
When a 32K Model 100 is first powered-on, it has about 29,638 bytes of RAM available (out of 32,768), and about 29,382 bytes when the BASIC interpreter is started.
Subsequently, comments and code readability were luxury items. As it is, having PERIOD.DO (the untokenized text version created from a download) and PERIOD.BA (tokenized BASIC) present at the same time leaves only 8,800 bytes of RAM, assuming the Model 100 isn't being used for anything else. If you download the PERIOD.DO file via TELCOM, you will need just about 21,000 bytes of unused RAM, until you can load the PERIOD.DO file into BASIC, save the program as tokenized BASIC (PERIOD.BA), and then delete the PERIOD.DO text file. After that step, you will recover over half of the RAM needed during the installation process, even while PERIOD.BA is running.
Why ".BA" and not ".BAS"? On the Model 100, only six characters are allowed for the file name, and only two characters for the file name extension. BASIC programs therefore use the extension ".BA", while text files (aka "documents") use the .DO extension.
The input is analyzed and categorized as one of the following:
| string "Help" or "?" | Display Help Menu |
| string "Menu" (Model 100) | Exit BASIC |
| string "System" (PC-DOS) | Exit BASIC |
| Non-zero non-integer number (a number with a decimal point) | Search by Element Atomic Weight |
| Non-zero integer number (whole number) | Search by Element Atomic Number, then by Element Atomic Weight |
| One or two letters | Search by Element Symbol, then by Element Name or Alias (only if two letters entered) |
| Three or more letters | Search by Element Name or Alias |
Lines 90 to 140 perform most of the parsing and dispatching described in the table above.
After a search has been completed and the results displayed, the program returns to line 80 so the user can enter the next item to be displayed.
Lines 10 to 70 are only executed on start-up.
10 CLEAR 200:CNT%=112:CR$=CHR$(13)+CHR$(10):DIM ELE$(CNT%):RESTORE 840:CLS 20 PRINT "Periodic Table Utility":PRINT "Version is 1(7) 7-Sep-2000 M100" 30 PRINT "Original Model 100 version, 1982": PRINT "Copr. 1982,1983,2000 Frank Durda IV" 40 PRINT "Ref: CRC Chemistry Ref, 52nd Edition":PRINT "Sargent-Welch Chemistry Tables 1980" 50 PRINT "Press <f1> or ?<Enter> for Help" 60 KEY 1,"Help"+CHR$(13):EL$="Element" 70 FOR T1%=1 TO CNT%:READ ELE$(T1%):NEXT T1% 80 LINE INPUT "Element? ";A$ 90 IF LEN(A$)=0 THEN 80 ELSE A$=LEFT$(A$,15) 100 IF A$="?" THEN 220 ELSE GOSUB 440:IF B$="Help" THEN 220 110 GOSUB 440:IF B$="Menu" THEN MENU 120 A=VAL(A$):A%=A:IF A=0 THEN 280 ELSE IF A<0 THEN 80 130 IF A%<>A OR INSTR(1,A$,".")>0 OR A%>CNT% THEN 150 140 NM%=A%:SH$=ELE$(NM%):GOSUB 350:GOTO 80
Rather than force the user to enter the atomic weight down to the last digit in order to have anything displayed, this routine searches for values that are "close" to what was provided, using the formula on line 190.
This routine is also called if an integer is entered with a value that is greater than the highest element number the program knows about, which is currently 112. The result is that if you enter 114, you will not be shown the unknown element 114, but Indium, which has an atomic weight of 114.82. Entering 114. 114.8 or 114.82 would also receive the same answer.
Line 210 reports that the search failed and returns to the main loop.
150 C$=STR$(A):C%=INSTR(1,C$,"."):IF C%=0 THEN D%=0 ELSE D%=LEN(MID$(C$,C%+1,20)) 160 GOSUB 270:FOR NM%=1 TO CNT% 170 SH$=ELE$(NM%):PP%=0:GOSUB 570:GOSUB 570 180 B=VAL(A$):IF B=0 THEN A$=MID$(A$,2,10):GOTO 180 190 B=INT(B*10^D%)/10^D%:IF A=B THEN GOSUB 350:GOTO 80 200 NEXT NM% 210 PRINT "Can't find that element":GOTO 80
Lines 220 through 260 form the help menu. Line 260 is altered in the PC-DOS version to exit BASIC back to a PC-DOS prompt.
On the Model 100, the string searches can take several seconds and may have to scan the entire element table twice, so any of the searches that can be slow call line 270 before they start to alert the user that the answer may take a moment to find.
220 CLS: PRINT "Command Formats Are:":PRINT "26 Displays ";EL$;" number 26" 230 PRINT "55.8 Displays the ";EL$;" with an":PRINT " Atomic Weight of Approx 55.8" 240 PRINT "XENON Displays the Element XENON":PRINT "W Displays Element with that" 250 PRINT " abbreviation (Tungsten)":PRINT "Press any key to continue"; 260 A$=INKEY$:IF A$="" THEN 260 ELSE PRINT CHR$(13);"<f8> Returns to main menu":GOTO 80 270 PRINT@263,"Searching...":RETURN
This code takes the number of characters entered and compares them against the same number of characters of each elements name, looking for a match. If the element has an alias (shown in parenthesis in the element table), it is also checked for a match. This allows both "Tungsten" and "Wolfram" to find element 74. The element with the lowest atomic number that matches a fractional-name search will be shown.
Normally, this routine only gets used if a string containing at least three letters is entered. Shorter text strings are checked to see if they match an actual element name first in another routine. If that routine fails to locate an element symbol, the search will return here to look for a partial name match. The search order means that "I" will locate "Iodine", but "IR" will find "Iron", as there is no element "IR", and even though Iron (Fe) has a lower atomic number.
If the element can't be found, control moves to line 210 that reports that the search has failed, a message shared with other search functions.
280 GOSUB 270:IF LEN(A$)<3 THEN 330 ELSE GOSUB 440
290 FOR NM%=1 TO CNT%:SH$=ELE$(NM%):C$=MID$(SH$,3,INSTR(3,SH$,"/")-3)
300 T1%=INSTR(1,C$,B$):T2%=INSTR(1,C$,"("+B$)
310 IF T1%=1 OR T2%>0 THEN GOSUB 350:GOTO 80
320 NEXT NM%:GOTO 210
If two letters are entered but a match is not found, the two letters are also used to search for a match with the first two letters of an element name or alias. (To disable performing the second search when only two letters are entered, change the "GOTO 290" in line 340 to "GOTO 210".)
Entering a single letter will not find anything but matching single letter symbol names. For example, entering "T" will not find any element, despite there being numerous two-character element symbols that start with T as well element names that start with T. This behavior is intentional. To enable element name searches when a single character symbol name search fails, on line 340, replace "GOTO 290" with
IF MID$(B$,2,1)=" " THEN B$=LEFT$(B$,1):GOTO 290 ELSE GOTO 290This change is not recommended in an educational environment.)
This code could also be adapted to support the IUPAC proposed three-letter symbols for recently-discovered elements, but there are arguments against this. First, the entire element table must be edited to make the element name start in the fourth character column, rather than the third as it does now. This adds a minimum of 224 bytes of storage demand while the program is running, which on the Model 100 is significant. Adjustments would also be needed on lines 90, 180, 280, 290, 330 and 340, and possibly others. Finally, the original 1982 version also ignored the IUPAC symbols that existed at that time, so leaving the table as it is presents this program closer to how it looked when it was originally developed.
330 GOSUB 440:B$=LEFT$(B$+" ",2):FOR NM%=1 TO CNT% 340 SH$=ELE$(NM%):IF LEFT$(SH$,2)=B$ THEN GOSUB 350:GOTO 80 ELSE NEXT NM%:GOTO 290
Lines 440-470 are used to convert the text that was entered so that the first letter is forced to uppercase and subsequent letters are forced to lowercase. The result can be used by the search routines.
350 PP%=0:GOSUB 570:CLS:PRINT LEFT$(A$,2);" ";NM%;" ";MID$(A$,3,30);" ";:GOSUB 570 360 PRINT A$:PRINT "Electron Distribution Crystal" 370 PRINT "K L M N O P Q";TAB(23);"Structure":GOSUB 570:GOSUB 480 380 PRINT "Electronegativity ";:GOSUB 570 390 IF A$="" THEN PRINT "---" ELSE PRINT A$ 400 GOSUB 570:CR%=VAL(A$):IF CR%>0 THEN GOSUB 590 ELSE T$="":PRINT@183,"Not Known":LINE(134,9)-(134,37),1 410 GOSUB 570:Y$="":Z%=INSTR(1,A$,"@"):IF Z%>0 THEN Y$=MID$(A$,Z%+1,40):A$=LEFT$(A$,Z%-1) 420 PRINT@200,;:IF VAL(LEFT$(A$,1))>0 THEN PRINT "Discovered in ";A$ ELSE PRINT A$ 430 IF LEN(Y$)>0 THEN PRINT Y$ 440 B%=ASC(LEFT$(A$,1)):IF B%>96 THEN B%=B%-32 450 B$=CHR$(B%):IF LEN(A$)=1 THEN RETURN ELSE FOR T1%=2 TO LEN(A$) 460 B%=ASC(MID$(A$,T1%,1)):IF B%<96 THEN B%=B%+32 470 B$=B$+CHR$(B%):NEXT T1%:RETURN
The combination of the formulas for low orbits and the hint for high orbits requires much less memory that putting explicit orbit information for each element in the element table.
This format of describing electron orbits may now be dated as it appears that some newer Chemistry references use a different method to describe this same information. To keep the program as close to the original 1982 version as possible, the original electron distribution display is still used.
480 T1%=0:S%=0:D$="":Q$="" 490 T1%=T1%+1:T2%=T1%:T1%=INSTR(T1%,A$,",") 500 IF T1%>0 THEN X$=MID$(A$,T2%,T1%-T2%):Q$=Q$+LEFT$(X$+" ",3):S%=S%+VAL(X$):GOTO 490 ELSE X$=MID$(A$,T2%):Q$=Q$+LEFT$(X$+" ",3):S%=S%+VAL(X$) 510 R%=NM%-S%:IF R%>1 THEN D$="2 ":ELSE 560 520 IF R%=2 THEN 560 ELSE D$=D$+"8 " 530 IF R%=10 THEN 560 ELSE D$=D$+"18 " 540 IF R%=28 THEN 560 ELSE D$=D$+"32 " 550 IF R%=60 THEN 560 ELSE D$=D$+"32 " 560 PRINT LEFT$(D$+Q$+"- - - - - -",20):RETURN
570 PP%=PP%+1:LP%=PP%:PP%=INSTR(PP%,SH$,"/"):IF PP%=0 THEN A$=MID$(SH$,LP%) ELSE A$=MID$(SH$,LP%,PP%-LP%) 580 RETURN
This routine draws the crystal lattice. Data stored in lines 760 through 830 describe all or a portion of the eight crystal lattices this program can draw. Technically, there are 14 possible crystal lattices in nature, but some do not appear in the element isotopes being shown. (Typically, the periodic table shows the most stable isotope.) Please see the discussion in the data section below on how the crystal types were selected for related information.
This routine uses several techniques to conserve storage in the tables that describe how to draw the crystal. For most crystals, the vectors in the table only describe how to draw the top surface of that crystal. As the top surface is drawn vector by vector, a "ghost" copy of the shape is drawn below it as well (creating the bottom of the crystal) as well as the vertical interconnecting lines (sides). The ghost is drawn by lines 670 and 680. The use of this technique means that to draw the Hexagonal crystal, only 7 sets of X/Y coordinates are needed instead of 21, the minimum number of points needed to draw the same 18 vectors.
If the X/Y coordinates contain a negative X coordinate, the "ghost" image is not drawn, and this mode is used to draw the interior of the Cubic Face Centered and Cubic Body Centered crystal shapes.
Finally, because of the limited screen resolution and area available, some crystals simply don't look right or are hard to distinguish from others if they are shown standing on end, which is what the "ghosted" drawing system produces. To deal with this for Rhombohedral and some of the other crystals, the ghosted part of the image can be skewed to the left or right by the setting in the third field of the crystal data area.
Because of how the Model 100 stores numbers, it was determined that the additional lines of code needed to hold the code that performs the ghosting and skewing was smaller than the amount of storage needed to list all of the vectors needed to completely draw the various crystals the traditional way.
Due to a difference in horizontal cell size for text between the Model 100 and PC-DOS platforms, the starting X and Y offset of all crystal drawings is adjusted on line 600. The position of the vertical line drawn by line 730 and the text position specified on 710 and 750 also change between the Model 100 and PC-DOS platform.
590 RESTORE 760 600 XF%=203:YF%=10:T$="":X$="":X1%=0 610 READ T1%,T2%,T3%,X$ 620 FOR T4%=1 TO T2%+1:READ T8%,T9%:IF T1%=CR% AND T4%=1 THEN T$=X$ 630 IF T1%<>CR% OR T4%=1 THEN 690 640 IF T8%<0 THEN READ T6%,T7%:T8%=ABS(T8%):VB%=-1:T4%=T4%+1 ELSE VB%=0 650 X1%=(T6%*4)+XF%:X2%=(T8%*4)+XF%:Y1%=(T7%*4)+YF%:Y2%=(T9%*4)+YF% 660 LINE (X1%,Y1%)-(X2%,Y2%),1:IF VB% THEN 700 670 X3%=((T6%+T3%)*4)+XF%:X4%=((T8%+T3%)*4)+XF%:Y3%=((T7%+7)*4)+YF%:Y4%=((T9%+7)*4)+YF% 680 LINE (X3%,Y3%)-(X4%,Y4%),1:LINE (X1%,Y1%)-(X3%,Y3%),1 690 T6%=T8%:T7%=T9% 700 NEXT T4%:IF X1%=0 THEN 610 710 T1%=143:T2%=1 720 T3%=INSTR(T2%,X$,"/") 730 IF T3%=0 THEN PRINT@T1%,MID$(X$,T2%,12);:LINE(134,9)-(134,37),1:RETURN 740 IF T3%-T2%<>0 THEN PRINT@T1%,MID$(X$,T2%,T3%-T2%); 750 T1%=T1%+40:T2%=T3%+1:GOTO 720
This data contains the instructions on how to draw the various crystal lattices. The crystal number is first, followed by the number of vectors to be drawn, so a 4 means five sets of X-Y points. Next comes the "ghost" skew setting, followed by the description, in which the '/' forces text placement. Finally, the X and Y coordinates for drawing the crystal. See the code section for details on how the drawing is performed and the function of skew and negative coordinates.
Crystal sizes were also chosen to ensure that the entire drawing (including ghost and any skew) would fit within a designated area of the screen. Exceeding the area usually results in BASIC aborting with a "FC Error", indicating a pixel was specified that is off-screen.
760 DATA 1,4,,"/ Cubic",3,,9,,7,2,1,2,3, 770 DATA 2,12,,"Cubic, Face/ Centered",3,,9,,7,2,1,2,3,,-4,5,4,6,-4,6,5,6,-5,6,5,5,-5,5,4,5 780 DATA 3,12,,"Cubic, Body/ Centered",3,,9,,7,2,1,2,3,,-3,,7,9,-9,,1,9,-3,7,7,2,-9,7,1,2 790 DATA 4,6,,"/ Hexagonal",1,1,4,,7,,8,1,5,2,2,2,1,1 800 DATA 5,4,-3,"/Rhombohedral",5,1,7,-1,8,2,6,4,5,1 810 DATA 6,4,,"/ Tetragonal",4,,8,,6,2,2,2,4, 820 DATA 7,4,,"/Orthorhombic",3,,8,,7,1,2,1,3, 830 DATA 8,4,2," /Monoclinic",1,,6,0,5,2,,2,1,
This is the element data, with each element described in a single string containing fields separated by slashes. The first field contains the two-character symbol (IUPAC has broken this above 109), followed by the element name. Field 2 is the atomic weight (surrounded by parentheses if the weight is an estimate), followed by the "hint" for computing the electron orbit distribution. Field 4 is the electronegativity, field 5 is the crystal type, followed by the historical notes. Empty numeric fields equal a value of "0".
Those of you who do nothing but chemistry and related research are probably composing letters to me right now about how I have slighted your colleagues, your university, hero, or mentor, by not giving them credit for discovering or co-discovering one element or the other, or I don't have what you consider to be the "right" crystal drawing or exhaustive historical data. Please put away your pen, cancel that e-mail composition, and read the following.
For each element, the atomic weight, electron orbit distribution and electronegativity were things that every reference I checked agreed-on. If you have disputes on these, please take them up with Universe management.
Starting at Element 104, there were many disputes over the years as to what these elements should be called, most notably US and USSR nuclear researchers of the 1960s and 1970s both claiming to have discovered the same element just slightly before the others found the same thing and both sides picking different names and symbols, while the IUPAC was offering third naming and symbol alternatives with really unpronounceable names for the same elements that only confused things further.
My chemistry and physics instructors of that day also thought this was all pretty stupid, with the "super powers" arguing over tiny amounts of matter, most of which are so fleeting that once it has been made, the matter doesn't last as long as a television soap commercial does, making this stuff somewhat useless, unless you happen to need yet-another way to make some long-lasting and hazardous matter that you won't be able to get rid of. Fortunately, most of that naming nonsense was finally resolved in 1995/1996, and the tables have been updated to reflect the names that appear to have been settled-on.
Another area of issue was the historical information. Because of the nonsense of the Cold War, I fully expected the names and dates of element discoveries above 100 to be unclear either due to national security veils or the "we made it first" Cold War squabbles, but I also found numerous differences of opinion on elements discovered one or two centuries earlier, where you would think the claims would be sorted-out by now.
Sometimes, the difference between one reference and another over who discovered something would be that one would list some person as discovering the element, while other references would list the first person to isolate the element or produce a pure-metal of the element as the person who made the discovery of the element, rather than whoever it was who really made the initial discovery. Other cases of dispute were even less understandable. Therefore, if the CRC handbook had the information, their version of history was used. The rest came from a variety of sources.
For crystal structure, I ran into a similar problems, and began to wonder how anything can get done in area of Chemistry if the scientists can't agree on the crystal shape of even a stable, common and well-understood element like Oxygen. Three references offered three different crystal structures for Oxygen (cubic, hexagonal and diamond), and failed to all agree for almost a quarter of all the elements that have known crystals. The CRC handbook would have been used as the final authority, but they frequently failed to provide crystal information on the simple elements in their tables, even though they listed freezing points for the elements in question. For example, CRC did not list a crystal structure for Mercury (Hg) and other sources did, but CRC did list a crystal structure for Mercury chromate (HgCrO4) and numerous other Mercury compounds, all of which was useless here.
Therefore, the crystal shape used is that which was stated in the 1980 edition of a Sargent-Welch periodic table I got back in 1982. The elements discovered since then don't last long enough or the researchers don't have enough of the atoms of that element in one place at the same time for anybody to actually know what their crystal shape is, so using this older reference wasn't a big problem.
I would accept corrections, but there seems little point since so many respected publishers have so many discrepancies over what should be universal constants. The lack of agreement means that having a non-chemist trying to verify a submitted correction would be impractical.
If someone finally comes up with a verified find of 114 (reported but unverified as of this writing, and no one claims to have seen 113), you can add them to the table yourself. After doing this, change the number of elements specified on line 10 to match the number now present in the table.
Note that you can't have any gaps in the table. If someone does verify 114, you have to put something in for the 113th element.
840 DATA "H Hydrogen/1.0079/1/2.2/4/1766 by Cavendish" 850 DATA "HeHelium/4.0026/2//1/1868 by Janssen" 860 DATA "LiLithium/6.941/1/.98/3/1817 by Arfvedson" 870 DATA "BeBeryllium/9.01218/2/1.57/4/1798 by Vauquelin" 880 DATA "B Boron/10.81/3/2.04/5/1808 by Davy" 890 DATA "C Carbon/12.011/4/2.55/4/Prehistoric Discovery" 900 DATA "N Nitrogen/14.0067/5/3.04/4/1772 by Rutherford" 910 DATA "O Oxygen/15.9994/6/3.44/8/1771 by Scheele" 920 DATA "F Fluorine/18.998403/7/3.98/8/1771 by Scheele.@Isolated by Moisson in 1886" 930 DATA "NeNeon/20.179/8//2/1898 by@Ramsay & Travers" 940 DATA "NaSodium/22.98977/1/.93/3/1807 by Davy" 950 DATA "MgMagnesium/24.305/2/1.31/4/1755@by Black" 960 DATA "AlAluminum/26.98154/3/1.61/2/1825@by Oerstead" 970 DATA "SiSilicon/28.0855/4/1.9/2/1824@by Berzelius" 980 DATA "P Phosphorus/30.97376/5/2.19/8/1669@by Brand" 990 DATA "S Sulfur/32.06/6/2.58/7/Refered to in Genesis@as Brimstone" 1000 DATA "ClChlorine/35.453/7/3.16/7/1774@by Scheele" 1010 DATA "ArArgon/39.948/8//2/1894@by Rayleigh & Ramsay" 1020 DATA "K Potassium/39.0983/8,1/.82/3/1807@by Davy" 1030 DATA "CaCalcium/40.08/8,2/1/2/1808@by Davy" 1040 DATA "ScScandium/44.9559/9,2/1.36/4/1876@by Nilson" 1050 DATA "TiTitanium/47.90/10,2/1.54/4/1791@by Gregor" 1060 DATA "V Vanadium/50.9415/11,2/1.63/3/1801@by del Rio" 1070 DATA "CrChromium/51.996/13,1/1.66/3/1790@by Vauquelin" 1080 DATA "MnManganese/54.9380/13,2/1.55/3/1770 by Kaim.@Isolated by Gahn in 1774" 1090 DATA "FeIron/55.847/14,2/1.83/3/Mentioned in Genesis@Tubal-Cain worked Iron" 1100 DATA "CoCobalt/58.9332/15,2/1.88/4/1735@by Brandt" 1110 DATA "NiNickel/58.70/16,2/1.91/2/China used in coins, 235BC.@Purified in 1751 by Cronstedt" 1120 DATA "CuCopper/63.546/18,1/1.9/2/Prehistoric Discovery" 1130 DATA "ZnZinc/65.38/18,2/1.65/4/Prehistoric Discovery" 1140 DATA "GaGallium/69.72/18,3/1.81/7/1875 by@Lecoq de Boisbaudran" 1150 DATA "GeGermanium/72.59/18,4/2.01/2/1886@by Winkler" 1160 DATA "AsArsenic/74.9216/18,5/2.18/5/1250@by Albertus Magnus" 1170 DATA "SeSelenium/78.96/18,6/2.55/4/1817@by Berzelius" 1180 DATA "BrBromine/79.904/18,7/2.96/7/1826@by Balard" 1190 DATA "KrKrypton/83.80/18,8//2/1898 by@Ramsay & Travers" 1200 DATA "RbRubidium/85.4678/8,1/.82/3/1861 by@Bunsen & Kirchoff" 1210 DATA "SrStrontium/87.62/8,2/.95/2/1790 by Crawford.@Metal form 1807 by Davy" 1220 DATA "Y Yttrium/88.9059/9,2/1.22/4/1794@by Gadolin" 1230 DATA "ZrZirconium/91.22/10,2/1.33/4/1789@by Klaproth" 1240 DATA "NbNiobium (Columbium)/92.9064/12,1/1.6/3/1801@by Hatchett" 1250 DATA "MoMolybdenum/95.94/13,1/2.16/3/1778@by Scheele" 1260 DATA "TcTechnetium (Masurium)/(98)/14,1/1.9/4/1937 by@Perrier & Segr`e" 1270 DATA "RuRuthenium/101.07/15,1/2.2/4/1827 by@Berzelius & Osann" 1280 DATA "RhRhodium/102.9055/16,1/2.28/2/1803-4@by Wollaston" 1290 DATA "PdPalladium/106.4/18/2.2/2/1803@by Wollaston" 1300 DATA "AgSilver/107.868/18,1/1.93/2/Mentioned in Genesis" 1310 DATA "CdCadmium/112.41/18,2/1.69/4/1817@by Strohmeyer" 1320 DATA "InIndium/114.82/18,3/1.78/6/1863 by@Reich & Richter" 1330 DATA "SnTin/118.69/18,4/1.96/6/Known to the ancients" 1340 DATA "SbAntimony/121.75/18,5/2.05/5/Known as a metal in@the early 17th century" 1350 DATA "TeTellurium/127.60/18,6/2.1/4/1782 by@Baron von Reichenstein" 1360 DATA "I Iodine/126.9045/18,7/2.66/7/1811@by Courtois" 1370 DATA "XeXenon/131.30/18,8//2/1898 by@Ramsay & Travers" 1380 DATA "CsCesium/132.9054/18,8,1/.79/3/1860 by@Bunsen & Kirchhoff" 1390 DATA "BaBarium/137.33/18,8,2/.89/3/1774 by Scheele.@Pure metal 1808 by Davy" 1400 DATA "LaLanthanum/138.9055/18,9,2/1.1/4/1839@by Mosander" 1410 DATA "CeCerium/140.12/20,8,2/1.12/2/1803 by@Klaproth, Berzelius & Hisinger" 1420 DATA "PrPraseodymium/140.9077/21,8,2/1.13/4/1885@by von Welsbach" 1430 DATA "NdNeodymium/144.24/22,8,2/1.14/4/1885@by von Welsbach" 1440 DATA "PmPromethium/(145)/23,8,2/1.13/4/1926 by Harris,@Hopkins, Rolla and Fernando." 1450 DATA "SmSamarium/150.4/24,8,2/1.17/5/1879@by Lecoq de Boisbaudran" 1460 DATA "EuEuropium/151.96/25,8,2/1.2/3/1901@by Demarcay" 1470 DATA "GdGadolinium/157.25/25,9,2/1.2/4/1880 by@Marignac & Lecoq de Boisbaudran" 1480 DATA "TbTerbium/158.9254/27,8,2/1.2/4/1843@by Mosander" 1490 DATA "DyDysprosium/162.50/28,8,2/1.22/4/1886 by@Lecoq de Boisbaudran" 1500 DATA "HoHolmium/164.9304/29,8,2/1.23/4/1878 by@Per Cleve" 1510 DATA "ErErbium/167.26/30,8,2/1.24/4/1842 by@Mosander" 1520 DATA "TmThulium/168.9342/31,8,2/1.25/4/1879@by Cleve" 1530 DATA "YbYtterbium/173.04/8,2/1.1/2/1878@by Marignac" 1540 DATA "LuLutetium/174.967/9,2/1.27/4/1907 by@Urbain, von Welsbach & James" 1550 DATA "HfHafnium/178.49/10,2/1.3/4/1923 by@D. Coster & G. von Hevesey" 1560 DATA "TaTantalum/180.9479/11,2/1.5/3/1802@by Ekeberg" 1570 DATA "W Tungsten (Wolfram)/183.85/12,2/2.36/3/1779@by Peter Woulfe" 1580 DATA "ReRhenium/186.207/13,2/1.9/4/1925 by@Noddack, Tacke & Berg" 1590 DATA "OsOsmium/190.2/14,2/2.2/4/1803@by Tennant" 1600 DATA "IrIridium/192.22/15,2/2.2/2/1803@by Tennant" 1610 DATA "PtPlatinum/195.09/17,1/2.28/2/1735 by@Ulloa & 1741 by Wood" 1620 DATA "AuGold/196.9665/18,1/2.54/2/Known and valued@from earliest times" 1630 DATA "HgMercury/200.59/18,2/2/5/Known to ancient@Chinese & Hindus" 1640 DATA "TlThallium/204.37/18,3/2.04/4/1861@by Crookes" 1650 DATA "PbLead/207.2/18,4/2.33/2/Long known;@Mentioned in Exodus" 1660 DATA "BiBismuth/208.9804/18,5/2.02/5/1753 by@Claude Geoffroy the Younger" 1670 DATA "PoPolonium/(209)/18,6/2/8/1898@by Mme. Curie" 1680 DATA "AtAstatine/(210)/18,7/2.2//1940 by@D.R. Corson, K.R. Mackenzie & E. Segr" 1690 DATA "RnRadon (Niton)/(222)/18,8//2/1900@by Dorn" 1700 DATA "FrFrancium/(223.0197)/18,8,1/.7/3/1939 by@Mlle. Marguerite Perey" 1710 DATA "RaRadium/226.0254/18,8,2/.9/3/1898 by@M. and Mme. Curie" 1720 DATA "AcActinium/227.0278/18,9,2/1.1/2/1899 by@Andre Debierne & 1902 by F. Giesel" 1730 DATA "ThThorium/232.03804/18,10,2/1.3/2/1828@by Berzelius" 1740 DATA "PaProtactinium/231.0359/20,9,2/1.5/7/1913@by K. Fajans & O. H. Gohring" 1750 DATA "U Uranium/238.029/21,9,2/1.38/7/Found in glass dated@about 79AD. Isolated in 1841 by Peligot" 1760 DATA "NpNeptunium/237.0482/23,8,2/1.36/7/1940@by McMillan & Abelson" 1770 DATA "PuPlutonium/(244)/24,8,2/1.28/8/1940 by@Seaborg, McMillan, Kennedy & Wahl" 1780 DATA "AmAmericium/(243)/25,8,2/1.3/4/1944 by@Seaborg, James, Morgan & Ghiorso" 1790 DATA "CmCurium/(247)/25,9,2/1.3//1944 by@Seaborg, James & Ghiorso" 1800 DATA "BkBerkelium/(247)/26,9,2/1.3//1949 by@Thompson, Ghiorso & Seaborg" 1810 DATA "CfCalifornium/(251)/29,8,2/1.3//1950 by@Thompson, Street, Ghiorso & Seaborg" 1820 DATA "EsEinsteinium/(252)/29,8,2/1.3//1952 in@debris of first H-bomb explosion" 1830 DATA "FmFermium/(257)/30,8,2/1.3//1952 in@debris of first H-bomb explosion" 1840 DATA "MdMendelevium/(258)/31,8,2/1.3//1955 by@Ghiorso, Harvey, Choppin & Thompson" 1850 DATA "NoNobelium/(259)/8,2/1.3//1958 by@Ghiorso, Sikkeland, Walton & Seaborg" 1860 DATA "LrLawrencium/(260)/9,2///1961 by@Ghiorso, Sikkeland, Larsh & Latimer" 1870 DATA "RfRutherfordium/(261)/10,2///1964 by Berkeley & Dubna." 1880 DATA "DbDubnium/(262)/11,2///1970 by Ghiorso" 1890 DATA "SgSeaborgium/(263)/12,2///by Ghiorso" 1900 DATA "BhBohrium/(264)/13,2///1981 by@Armbruster and Munzenberg" 1910 DATA "HsHassium/(265)/14,2///1983 by@Armbruster and Munzenberg" 1920 DATA "MtMeitnerium/(266)/15,2///1984 by@Armbruster and Munzenberg" 1930 DATA "--Element 110/(269)/17,1///1994 by Hofmann, Ninov,@Hessberger and others" 1940 DATA "--Element 111/(272)/18,1///1994 by Hofmann, Ninov,@Hessberger and others" 1950 DATA "--Element 112/(277)/18,2///Single atom made in 1996 by@Armbruster and Munzenberg"
[Copyright 1982,1983,2000,2002 Frank Durda IV, All Rights Reserved. Mirroring of any material on this site in any form is expressly prohibited. The official web site for this material is: http://nemesis.lonestar.org Contact this address for use clearances: clearance at nemesis.lonestar.org Comments and queries to this address: web_software_2011 at nemesis.lonestar.org]
Return to the PERIOD Index page
Visit the nemesis.lonestar.org home page and index